SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
CREATE proc [dbo].[procAccessExport]
@s_tbname varchar(4000)='SampleData', --表名列表用逗号分隔,不指定将导出所有表
@path nvarchar(1000), --文件存放目录
@fname nvarchar(250), --文件名
@password varchar(20)='', --Access数据库的密码
@s_user sysname='', --提示连接错误则需提供sql服务器登陆用户名及密码
@s_password varchar(50)=''
as
set nocount on
exec sp_configure 'show advanced options',1 reconfigure
exec sp_configure 'Ole Automation Procedures',1 reconfigure --启用 Ole 自动化
declare @err int,@src nvarchar(255)
,@desc nvarchar(255),@out int
declare @obj int,@constr nvarchar(1000)
,@sql varchar(8000),@fdlist varchar(8000)
--参数检测
if isnull(@fname,'')='' set @fname='data.mdb'
--检查文件是否已经存在
if right(@path,1)<>'\' set @path=@path+'\'
create table #tb(a bit,b bit,c bit)
set @sql=@path+@fname
insert into #tb exec master..xp_fileexist @sql
--数据库创建
select @sql=@path+@fname
,@constr='Provider=Microsoft.Jet.OLEDB.4.0;Data Source='+@sql
+case isnull(@password,'') when '' then ''
else ';Jet OLEDB:Database Password='+@password end
if not exists(select 1 from #tb where a=1)
begin
exec @err=sp_OACreate 'ADOX.Catalog',@obj out
if @err<>0 goto lberr
exec @err=sp_OAMethod @obj,'Create',@out out,@constr
if @err<>0 goto lberr
exec @err=sp_OADestroy @obj
if @err<>0 goto lberr
end
--连接数据库
exec @err=sp_OACreate 'adodb.connection',@obj out
if @err<>0 goto lberr
exec @err=sp_OAMethod @obj,'open',null,@constr
if @err<>0 goto lberr
--导出处理
declare @tbname sysname,@s varchar(8000)
set @s=case isnull(@s_tbname,'') when '' then ''
else ' and name in('''+replace(@s_tbname,',',''',''')+''')' end
exec('declare tb cursor global for select name from sysobjects where xtype=''U'''+@s)
open tb
fetch next from tb into @tbname
while @@fetch_status=0
begin
--删除现有的表
set @sql='drop table ['+@tbname+']'
exec @err=sp_OAMethod @obj,'execute',@out out,@sql
--导出表
if isnull(@s_user,'')=''
set @sql='SELECT * into ['+@tbname
+'] FROM [ODBC;Driver=SQL Server;Server='+ @@servername
+';database='+db_name()+'].['+@tbname+']'
else
set @sql='SELECT * into ['+@tbname
+'] FROM [ODBC;Driver=SQL Server;Server='+ @@servername
+';Uid='+@s_user+';Pwd='+isnull(@s_password,'')
+';database='+db_name()+'].['+@tbname+']'
exec @err=sp_OAMethod @obj,'execute',@out out,@sql
if @err<>0 goto lberr
fetch next from tb into @tbname
end
close tb
deallocate tb
--关闭Access
exec @err=sp_OAMethod @obj,'close',null
if @err<>0 goto lberr
--释放对象
exec @err=sp_OADestroy @obj
return
lberr:
exec sp_oageterrorinfo 0,@src out,@desc out
if @obj<>0 exec @err=sp_OADestroy @obj
lbexit:
select cast(@err as varbinary(4)) as 错误号
,@src as 错误源,@desc as 错误描述
select @sql,@constr,@fdlist
exec sp_configure 'Ole Automation Procedures',0 reconfigure
exec sp_configure 'show advanced options',0 reconfigure
go
exec procAccessExport @s_tbname=''
,@path='D:\'
,@fname='data.mdb'